defmodule ToweropsWeb.OrgLive.New do
  @moduledoc false
  use ToweropsWeb, :live_view

  alias Towerops.Organizations
  alias Towerops.Organizations.Organization

  @impl true
  def mount(_params, _session, socket) do
    changeset = Organizations.change_organization(%Organization{})

    {:ok,
     socket
     |> assign(:page_title, "New Organization")
     |> assign(:form, to_form(changeset))}
  end

  @impl true
  def handle_event("validate", %{"organization" => org_params}, socket) do
    changeset =
      %Organization{}
      |> Organizations.change_organization(org_params)
      |> Map.put(:action, :validate)

    {:noreply, assign(socket, :form, to_form(changeset))}
  end

  @impl true
  def handle_event("save", %{"organization" => org_params}, socket) do
    user = socket.assigns.current_scope.user

    case Organizations.create_organization(org_params, user.id) do
      {:ok, organization} ->
        {:noreply,
         socket
         |> put_flash(:info, "Organization created successfully")
         |> push_navigate(to: ~p"/orgs/#{organization.slug}")}

      {:error, %Ecto.Changeset{} = changeset} ->
        {:noreply, assign(socket, :form, to_form(changeset))}
    end
  end
end