prop/test/microwaveprop/weather_grid_test.exs

defmodule Microwaveprop.WeatherGridTest do
  use Microwaveprop.DataCase, async: true

  alias Microwaveprop.Repo
  alias Microwaveprop.Weather

  describe "latest_weather_grid/1" do
    test "returns grid data for latest valid_time within bounds" do
      now = DateTime.truncate(DateTime.utc_now(), :second)

      insert_hrrr_profile(%{
        lat: 32.125,
        lon: -97.375,
        valid_time: now,
        surface_temp_c: 25.0,
        surface_dewpoint_c: 18.0,
        surface_pressure_mb: 1013.0,
        hpbl_m: 500.0,
        pwat_mm: 30.0,
        min_refractivity_gradient: -280.0,
        ducting_detected: true
      })

      insert_hrrr_profile(%{
        lat: 32.250,
        lon: -97.375,
        valid_time: now,
        surface_temp_c: 26.0,
        surface_dewpoint_c: 19.0,
        surface_pressure_mb: 1012.0,
        hpbl_m: 600.0,
        pwat_mm: 32.0,
        min_refractivity_gradient: -150.0,
        ducting_detected: false
      })

      bounds = %{"south" => 32.0, "north" => 33.0, "west" => -98.0, "east" => -97.0}
      result = Weather.latest_weather_grid(bounds)

      assert length(result) == 2
      point = Enum.find(result, &(&1.lat == 32.125))
      assert point.temperature == 25.0
      assert point.dewpoint_depression == 7.0
      assert point.bl_height == 500.0
      assert point.pwat == 30.0
      assert point.refractivity_gradient == -280.0
      assert point.ducting == true
    end

    test "returns empty list when no data exists" do
      bounds = %{"south" => 32.0, "north" => 33.0, "west" => -98.0, "east" => -97.0}
      assert Weather.latest_weather_grid(bounds) == []
    end

    test "only returns points on 0.125 grid" do
      now = DateTime.truncate(DateTime.utc_now(), :second)

      insert_hrrr_profile(%{
        lat: 32.125,
        lon: -97.375,
        valid_time: now,
        surface_temp_c: 25.0,
        surface_dewpoint_c: 18.0,
        surface_pressure_mb: 1013.0,
        hpbl_m: 500.0,
        pwat_mm: 30.0
      })

      insert_hrrr_profile(%{
        lat: 32.1337,
        lon: -97.3821,
        valid_time: now,
        surface_temp_c: 25.0,
        surface_dewpoint_c: 18.0,
        surface_pressure_mb: 1013.0,
        hpbl_m: 500.0,
        pwat_mm: 30.0
      })

      bounds = %{"south" => 32.0, "north" => 33.0, "west" => -98.0, "east" => -97.0}
      result = Weather.latest_weather_grid(bounds)

      assert length(result) == 1
      assert hd(result).lat == 32.125
    end

    test "uses most recent valid_time only" do
      old = DateTime.utc_now() |> DateTime.add(-7200, :second) |> DateTime.truncate(:second)
      new = DateTime.truncate(DateTime.utc_now(), :second)

      insert_hrrr_profile(%{
        lat: 32.125,
        lon: -97.375,
        valid_time: old,
        surface_temp_c: 20.0,
        surface_dewpoint_c: 15.0,
        surface_pressure_mb: 1010.0,
        hpbl_m: 400.0,
        pwat_mm: 25.0
      })

      insert_hrrr_profile(%{
        lat: 32.125,
        lon: -97.375,
        valid_time: new,
        surface_temp_c: 28.0,
        surface_dewpoint_c: 20.0,
        surface_pressure_mb: 1015.0,
        hpbl_m: 700.0,
        pwat_mm: 35.0
      })

      bounds = %{"south" => 32.0, "north" => 33.0, "west" => -98.0, "east" => -97.0}
      result = Weather.latest_weather_grid(bounds)

      assert length(result) == 1
      assert hd(result).temperature == 28.0
    end
  end

  describe "weather_point_detail/3" do
    test "returns all fields for a single grid point" do
      now = DateTime.truncate(DateTime.utc_now(), :second)

      insert_hrrr_profile(%{
        lat: 32.125,
        lon: -97.375,
        valid_time: now,
        surface_temp_c: 25.0,
        surface_dewpoint_c: 18.0,
        surface_pressure_mb: 1013.0,
        hpbl_m: 500.0,
        pwat_mm: 30.0,
        min_refractivity_gradient: -280.0,
        ducting_detected: true
      })

      result = Weather.weather_point_detail(32.15, -97.40, now)

      assert result.lat == 32.125
      assert result.temperature == 25.0
      assert result.surface_pressure_mb == 1013.0
    end

    test "returns nil when no data at point" do
      now = DateTime.truncate(DateTime.utc_now(), :second)
      assert Weather.weather_point_detail(32.15, -97.40, now) == nil
    end
  end

  defp insert_hrrr_profile(attrs) do
    now = DateTime.truncate(DateTime.utc_now(), :second)

    defaults = %{
      id: Ecto.UUID.bingenerate(),
      run_time: DateTime.add(attrs.valid_time, -3600, :second),
      profile: [],
      surface_refractivity: nil,
      min_refractivity_gradient: nil,
      ducting_detected: nil,
      duct_characteristics: nil,
      inserted_at: now,
      updated_at: now
    }

    entry = Map.merge(defaults, attrs)
    Repo.insert_all("hrrr_profiles", [entry])
  end
end