defmodule MicrowavepropWeb.LiveTableFooter do
  @moduledoc false
  use Phoenix.Component

  def render(assigns) do
    options = assigns.options
    table_options = assigns.table_options
    paginate? = get_in(options, ["pagination", "paginate?"])
    mode = get_in(table_options, [:pagination, :mode])

    assigns =
      assigns
      |> assign(:show_pagination?, paginate? && mode != :infinite_scroll)
      |> assign(:page, parse_page(get_in(options, ["pagination", "page"])))
      |> assign(:has_next_page?, get_in(options, ["pagination", :has_next_page]) || false)

    ~H"""
    <nav
      :if={@show_pagination?}
      class="flex items-center justify-between px-4 py-3 sm:px-6"
      aria-label="Pagination"
    >
      <p class="hidden sm:block text-sm opacity-60">
        Page <span class="font-medium text-base-content">{@page}</span>
      </p>

      <div class="join">
        <button
          type="button"
          class="btn btn-sm join-item"
          phx-click="sort"
          phx-value-page={@page - 1}
          disabled={@page == 1}
          aria-label="Previous page"
        >
          «
        </button>
        <button type="button" class="btn btn-sm join-item btn-active pointer-events-none">
          {@page}
        </button>
        <button
          type="button"
          class="btn btn-sm join-item"
          phx-click="sort"
          phx-value-page={@page + 1}
          disabled={!@has_next_page?}
          aria-label="Next page"
        >
          »
        </button>
      </div>
    </nav>
    """
  end

  defp parse_page(page) when is_integer(page), do: page
  defp parse_page(page) when is_binary(page), do: String.to_integer(page)
  defp parse_page(_), do: 1
end