defmodule MicrowavepropWeb.UserRegistrationControllerTest do
  use MicrowavepropWeb.ConnCase, async: true

  import Microwaveprop.AccountsFixtures

  describe "GET /users/register" do
    test "renders registration page", %{conn: conn} do
      conn = get(conn, ~p"/users/register")
      response = html_response(conn, 200)
      assert response =~ "Register"
      assert response =~ ~p"/users/log-in"
      assert response =~ ~p"/users/register"
      assert response =~ "Callsign"
      assert response =~ "Name"
      assert response =~ "Confirm password"
    end

    test "redirects if already logged in", %{conn: conn} do
      conn = conn |> log_in_user(user_fixture()) |> get(~p"/users/register")

      assert redirected_to(conn) == ~p"/"
    end
  end

  describe "POST /users/register" do
    test "creates account, sends confirmation email, does not log in", %{conn: conn} do
      email = unique_user_email()

      conn =
        post(conn, ~p"/users/register", %{
          "user" => valid_user_attributes(email: email)
        })

      refute get_session(conn, :user_token)
      assert redirected_to(conn) == ~p"/users/log-in"

      assert Phoenix.Flash.get(conn.assigns.flash, :info) =~
               ~r/Please check .* for a confirmation link/

      # An unconfirmed user and a confirmation token should exist
      user = Microwaveprop.Accounts.get_user_by_email(email)
      assert user
      assert is_nil(user.confirmed_at)

      assert Microwaveprop.Repo.get_by(Microwaveprop.Accounts.UserToken,
               user_id: user.id,
               context: "confirm"
             )
    end

    test "renders errors when required fields are missing", %{conn: conn} do
      conn =
        post(conn, ~p"/users/register", %{
          "user" => %{"email" => "with spaces"}
        })

      response = html_response(conn, 200)
      assert response =~ "Register"
      assert response =~ "must have the @ sign and no spaces"
    end
  end
end
